Fil:Interferenz.jpg

Fra testwiki
Hopp til navigering Hopp til søk
Opprinnelig fil (2 000 × 2 000 piksler, filstørrelse: 634 KB, MIME-type: image/jpeg)

Denne filen er fra Wikimedia Commons og kan brukes av andre prosjekter. Beskrivelsen fra filbeskrivelsessida vises nedenfor.

Beskrivelse

Beskrivelse
Deutsch: Simuliertes Interferenzbild zweier punktförmiger Quellen mit gleicher Wellenlänge. Die Lagen der Quellen sind durch Kreuze gekennzeichnet, die Maxima beider Wellen durch farbige Kreise.
Dato
Kilde Eget verk
Opphavsperson Dr. Schorsch 12:32, 19 Apr 2005 (UTC) (Dr. Schorsch (talk))

Lisensiering

Jeg, rettighetsinnehaver av dette arbeidet, publiserer det herved under følgende lisenser:
GNU head Det tillates at dette dokumentet kopieres, distribueres og/eller modifiseres under retningslinjene som beskrevet i GNU fri dokumentasjonslisens, versjon 1.2 eller senere utgave utgitt av Free Software Foundation; med alle seksjoner, uten noen forsidetekster og baksidetekster. En kopi av lisensen er inkludert i avsnittet GNU Free Documentation License.
w:no:Creative Commons
navngivelse del på samme vilkår
Denne filen er lisensiert under lisensene Creative Commons Navngivelse-DelPåSammeVilkår 3.0 Unported, 2.5 Generisk, 2.0 Generisk og 1.0 Generisk.
Du står fritt:
  • til å dele – til å kopiere, distribuere og overføre verket
  • til å blande – til å endre verket
Under de følgende betingelsene:
  • navngivelse – Du må kreditere verket på passende vis, lenke til lisensen og indikere hvorvidt det har blitt gjort endringer. Du kan gjøre det på enhver rimelig måte, men ikke på en måte som antyder at lisensgiveren støtter deg eller din bruk av verket.
  • del på samme vilkår – Dersom du remikser, omarbeider eller på annen måte bygger på dette verket, må du kun distribuere resultatet under den samme eller en samsvarende lisens som denne.
Du kan velge lisens etter eget valg.

Source Code

This is the source code of the program I used to create this image. Click on “Show source code” to display it.

The following program is under the GNU General Public License (GPL).

Dette verk er fri programvare; du kan distribuere det og/eller modifisere det under vilkårene i GNU General Public License som publisert av Free Software Foundation; i versjon 2 av lisensen eller en senere versjon. Dette verk er distribuert i håp om at det skal være anvendelig, men uten noen garanti; uten selv underforstått garanti om salgbarhet eller egnethet til et bestemt formål. Se versjon 2 og versjon 3 av GNU General Public License for flere detaljer. 

; Program Written in IDL (Interactive Data Language)
; Free Interpreter availible at www.rsinc.com
; Written by Georg Wiora
; This Program is under the  GNU General Public License (GPL)  
;
; Create a display of interference patterns
; Save this text as file "Interference2.pro" to run it.
 
; Draw a circle
PRO circle,x,y,r,_REF_EXTRA=ex
  n=ULONG(!DPI*r) > 1
  phi = FINDGEN(n)/FLOAT(n)*2*!DPI
  x1 = r*COS(phi)+x
  y1 = r*SIN(phi)+y
  PLOTS,[x1,x1[0]],[y1,y1[0]],_STRICT_EXTRA=ex
END

; Compute the interference
PRO Interference2
   ; Final Image Size
  siz=2000
  ; No display if larger than 800x1600 pixel
  pixmap=SIZ GT 800
  ; Wavelength in Pixel
  lambda=160
  ; Half distance of the sources
  dhalb = lambda

  ; Compute the distance of each point in an array from the
  ; center point: This is the phase of the signal
  d1 = SHIFT(DIST(siz*2,siz),siz,siz/2)
  ; Sinus of distace with 0 LE amplitude LE 2
  f = SIN(d1/lambda*2*!DPI)+1
  ; Compute Interference
  inter = SHIFT(f,-dhalb,0)+SHIFT(f,dhalb,0)
  ; Get maximum and minimum
  ma = MAX(inter,MIN=mi)
  ; Two colors are reserved for marking, the rest is gray scale
  ; Scale interference to byte range [0..253]
  inter = BYTE((TEMPORARY(inter)-mi)/(ma-mi)*253)

  ; Use lookup table to display
  DEVICE,DECOMPOSED=0
  ; Gray scale
  LOADCT,0
  ; Half length of center cross bars in pixel
  cs=30
  ; Half width of center cross bars in pixel
  cb=3
  
  ; Set mark for center
  ; Horizontal left
  inter[siz-dhalb-cs:siz-dhalb+cs, siz/2-cb:siz/2+cb] = 254
  ; Vertical left
  inter[siz-dhalb-cb:siz-dhalb+cb, siz/2-cs:siz/2+cs] = 254
  ; Horizontal right
  inter[siz+dhalb-cs:siz+dhalb+cs, siz/2-cb:siz/2+cb] = 255
  ; Vertical right
  inter[siz+dhalb-cb:siz+dhalb+cb, siz/2-cs:siz/2+cs] = 255

  ; Open a visible or invisible window (depends on pixmap flag)
  WINDOW,XSIZE=2*siz,YSIZE=siz,PIXMAP=pixmap
  ; Display the interference (only gray scale!)
  TV,inter
  ; Draw circles on maximum locations   
  FOR i=0,2.5*siz/lambda DO $
  BEGIN
    ; Maximum location left
    circle,siz-dhalb,siz/2,(i+0.25)*lambda,THICK=6,/DEVICE,COLOR=254
    ; Maximum location right
    circle,siz+dhalb,siz/2,(i+0.25)*lambda,THICK=6,/DEVICE,COLOR=255
  ENDFOR

  ; Colortable 0-253 as gray scake
  r = FINDGEN(256)/253*255
  g=r
  b=r
  ; 254 is green
  r[254]=0
  b[254]=0
  g[254]=255
  ; 255 is red
  r[255]=255
  b[255]=0
  g[255]=0

  ; Read image from display
  im=TVRD()
  ; Crop invalid borders
  im = im[siz/2:3*siz/2-1,*]

  ; Save as PNG with colortable
  WRITE_PNG,'Interference2.png',im,r,g,b
  ; Convert to truecolor and write JPEG
  imt = [[[r[im]]],[[g[im]]],[[b[im]]]]
  ; smooth image a little bit (saves bandwith in jpeg and is OK
  ; with high resolution)
  imt[*,*,0] = SMOOTH(imt[*,*,0],3,/EDGE_TRUNCATE)
  imt[*,*,1] = SMOOTH(imt[*,*,1],3,/EDGE_TRUNCATE)
  imt[*,*,2] = SMOOTH(imt[*,*,2],3,/EDGE_TRUNCATE)
  ; Write as jpeg
  WRITE_JPEG,'Interference2.jpg',TEMPORARY(imt),/PROGRESSIVE,$
             QUALITY=90, TRUE=3 
END

Bildetekster

Legg til en kort forklaring på hva filen representerer
Simulated interference image of two point sources of equal wavelength and amplitude

Elementer som er med i denne fila

motiv

interferens

Filhistorikk

Klikk på et tidspunkt for å vise filen slik den var på det tidspunktet.

Dato/klokkeslettMiniatyrbildeDimensjonerBrukerKommentar
nåværende19. apr. 2005 kl. 15:26Miniatyrbilde av versjonen fra 19. apr. 2005 kl. 15:262 000 × 2 000 (634 KB)wikimediacommons>Xorx

Den følgende siden bruker denne filen:

Hentet fra «https://no.wikibooks.beta.math.wmflabs.org/wiki/Fil:Interferenz.jpg»